source: verona/oRTP/CMakeLists.txt @ 227:7cf64dc0debb

project(ortp)

cmake_minimum_required(VERSION 2.6)

file(GLOB ORTP_SRC_ALL src/*.c)
file(GLOB ORTP_SRC_WIN32 src/dll_entry.c)
set(ORTP_SRC ${ORTP_SRC_ALL})

if(NOT WIN32)
  list(REMOVE_ITEM ORTP_SRC ${ORTP_SRC_WIN32})
endif(NOT WIN32)

if(CMAKE_UNDER_CE)
  set(ORTP_SRC ${ORTP_SRC} build/wince/ortp.def)
endif(CMAKE_UNDER_CE)

if(WIN32 AND NOT CMAKE_UNDER_CE)
  set(ORTP_SRC ${ORTP_SRC} build/win32native/ortp.def)
endif(WIN32 AND NOT CMAKE_UNDER_CE)

have_vars(dlfcn.h inttypes.h linux/soundcard.h memory.h
   poll.h stdint.h strings.h string.h sys/audio.h stdlib.h fcntl.h sys/stat.h sys/uio.h unistd.h sys/time.h sys/types.h semaphore.h)

if(ANDROID)
  set(CMAKE_THREAD_LIBS_INIT "-lc")
endif()
include(FindThreads)
include(FindOpenSSL)

set(ORTP_MAJOR_VERSION __ZERO__)
set(ORTP_MINOR_VERSION "16")
set(ORTP_MICRO_VERSION __ZERO__)
#set(ORTP_DEFAULT_THREAD_STACK_SIZE __ZERO__)
set(ORTP_VERSION "0.${ORTP_MINOR_VERSION}.0")
set(PACKAGE "ortp")
set(PACKAGE_BUGREPORT "ortp")
set(PACKAGE_NAME "ortp")
set(PACKAGE_STRING "${PACKAGE} ${ORTP_VERSION}")
set(POSIXTIMER_INTERVAL 10000)
set(SO_REUSE_ADDR 1)
set(VERSION ${ORTP_VERSION})

if(ANDROID)
  set(HAVE_DEV_RANDOM 1)
endif(ANDROID)

if(WIN32 AND NOT CMAKE_UNDER_CE)
        set(CMAKE_REQUIRED_LIBRARIES WS2_32.Lib)
        set(CMAKE_REQUIRED_FLAGS /FIwinsock2.h)
endif(WIN32 AND NOT CMAKE_UNDER_CE)
if(CMAKE_UNDER_CE)
        set(CMAKE_REQUIRED_LIBRARIES WS2.Lib)
        set(CMAKE_REQUIRED_FLAGS /FIwinsock2.h)
endif(CMAKE_UNDER_CE)
have_function(select socket)

set(STDC_HEADERS true)

configure_file("${CMAKE_CURRENT_SOURCE_DIR}/ortp-config.h.cmake" "${CMAKE_CURRENT_BINARY_DIR}/ortp-config.h")
add_definitions( -DHAVE_CONFIG_H )

include_directories(include ${CMAKE_CURRENT_BINARY_DIR})

add_library(ortp SHARED ${ORTP_SRC})


set(ORTP_LINK_LIBRARIES)



if(USE_CSL)
  add_definitions( -DHAVE_CSL )
  include_directories(${CSL_INCLUDE_DIRS} ${ACSLCORE_INCLUDE_DIRS})
  set(ORTP_LINK_LIBRARIES ${ORTP_LINK_LIBRARIES} ${ACSLCORE_LIBRARIES})
  if(WIN32)
        add_definitions(-DISL_DLLENTRY=__declspec\(dllexport\))
  else(WIN32)
        add_definitions(-DISL_DLLENTRY=)
  endif(WIN32)
endif(USE_CSL)

if(WIN32  AND NOT CMAKE_UNDER_CE)
  set(ORTP_LINK_LIBRARIES ${ORTP_LINK_LIBRARIES} ws2_32 winmm)
endif(WIN32  AND NOT CMAKE_UNDER_CE)
if(CMAKE_UNDER_CE)
  set(ORTP_LINK_LIBRARIES ${ORTP_LINK_LIBRARIES} ws2 mmTimer)
endif(CMAKE_UNDER_CE)
if(OPENSSL_FOUND)
  set(ORTP_LINK_LIBRARIES ${ORTP_LINK_LIBRARIES} ssl crypto)
endif(OPENSSL_FOUND)
target_link_libraries(ortp ${ORTP_LINK_LIBRARIES})
if(NOT ANDROID)
  set_target_properties(ortp PROPERTIES VERSION ${ORTP_VERSION} SOVERSION ${ORTP_VERSION})
endif()

set(ORTP_INCLUDE_DIRS "${CMAKE_CURRENT_SOURCE_DIR}/include" CACHE PATH "Include path for oRTP library")
set(ORTP_LIB_DIR ${LIBRARY_OUTPUT_DIRECTORY} CACHE PATH "Output directory for oRTP library")
set(ORTP_LIBRARIES ortp CACHE STRING "ortp libraries")
#subdirs(src/tests)

if (BUILD_ORTP_TEST)
  file(GLOB ORTP_TEST_SRC  src/tests/*.c)
  foreach(i ${ORTP_TEST_SRC})
    string(REPLACE ".c" "" prog ${i})
    string(REGEX REPLACE ".*/" "" prog ${prog})
    message("Adding executable ${prog} ${i})")
    add_executable(${prog} ${i})
    target_link_libraries(${prog} ortp)
  endforeach(i)
endif (BUILD_ORTP_TEST)